VSTSpeek_flake/flake.nix
2026-05-26 20:39:32 +02:00

62 lines
1.7 KiB
Nix

{
description = "flake for the linux port of VST Speek";
inputs = {
flake-parts.url = "github:hercules-ci/flake-parts";
nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
nixpkgs-qt4.url = "github:NixOS/nixpkgs/nixos-22.11";
};
outputs =
inputs@{ flake-parts, ... }:
flake-parts.lib.mkFlake { inherit inputs; } {
imports = [
inputs.flake-parts.flakeModules.easyOverlay
];
systems = [ "x86_64-linux" ];
perSystem =
{
config,
self',
inputs',
pkgs,
system,
...
}:
let
pkgs-qt4 = inputs.nixpkgs-qt4.legacyPackages.${system};
in
{
overlayAttrs = {
inherit (config.packages) VSTSpeek;
};
packages.VSTSpeek = pkgs.stdenv.mkDerivation {
pname = "VSTSpeek";
version = "1.0.0";
src = pkgs.fetchurl {
url = "https://blog.wavosaur.com/download/linux/VstSpeek3-x64.so.tar.gz";
hash = "sha256-xWSprHBU/7zz/KdH8nF6elwQRE29DEO9uDC4qie4n6g=";
};
nativeBuildInputs = [
pkgs.autoPatchelfHook
pkgs.patchelf
];
buildInputs = with pkgs; [
stdenv.cc.cc.lib # libstdc++
pkgs-qt4.qt4
];
dontUnpack = true;
dontBuild = true;
dontConfigure = true;
installPhase = ''
mkdir -p $out/lib/vst
tar -xzf $src -C $out/lib/vst/
patchelf --add-rpath ${pkgs-qt4.qt4}/lib $out/lib/vst/VstSpeek3.so
'';
};
packages.default = self'.packages.VSTSpeek;
};
flake = {
};
};
}