This commit is contained in:
Dario48 2026-05-26 20:03:10 +02:00
commit 864edf8846

53
flake.nix Normal file
View file

@ -0,0 +1,53 @@
{
description = "flake for the linux port of VST Speek";
inputs = {
flake-parts.url = "github:hercules-ci/flake-parts";
nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
};
outputs =
inputs@{ flake-parts, ... }:
flake-parts.lib.mkFlake { inherit inputs; } {
imports = [
inputs.flake-parts.flakeModules.easyOverlay
];
systems = [ "x86_64-linux" ];
perSystem =
{
config,
self',
inputs',
pkgs,
system,
...
}:
{
overlayAttrs = {
inherit (config.packages) VSTSpeek;
};
packages.VSTSpeek = pkgs.stdenv.mkDerivation {
pname = "VSTSpeek";
version = "1.0.0";
src = pkgs.fetchurl {
url = "https://blog.wavosaur.com/download/linux/VstSpeek3-x64.so.tar.gz";
hash = "sha256-xWSprHBU/7zz/KdH8nF6elwQRE29DEO9uDC4qie4n6g=";
};
nativeBuildInputs = [ pkgs.autoPatchelfHook ];
buildInputs = with pkgs; [
stdenv.cc.cc.lib # libstdc++
];
dontUnpack = true;
dontBuild = true;
dontConfigure = true;
installPhase = ''
mkdir -p $out/lib/vst
tar -xzf $src -C $out/lib/vst/
'';
};
packages.default = self'.packages.VSTSpeek;
};
flake = {
};
};
}